ReduceCSpec.hs

{-# LANGUAGE BlockArguments #-}
{-# LANGUAGE LambdaCase #-}

module ReduceCSpec where

import Control.Monad

import System.Directory
import System.FilePath
import Test.Hspec

import Test.Hspec.Glitter

import qualified Language.C as C
import qualified Text.PrettyPrint as P

import Control.Monad.RTree (extract, iinputs)
import Data.Functor
import Data.RPath
import qualified Language.C.System.GCC as C
import ReduceC
import System.Process.Typed

spec :: Spec
spec = do
  cases <- runIO (listDirectory "test/cases")

  forM_ cases \cname -> do
    let cfrom = "test/cases" </> cname

    c <- runIO $ parse cfrom

    let expected = "test/expected" </> dropExtensions cname
    onGlitterWith (expected </> "main.c") (\fp () -> render fp c) do
      it "should be valid" . foldMap $ \cf -> do
        validate cf

      it "should be parsed equally" . foldMap $ \cf -> do
        C.parseCFilePre cf >>= \case
          Left err -> fail (show err)
          Right c' -> c' $> () `shouldBe` c $> ()

    describe "reduction" do
      it "should extract itself" do
        extract (reduceC c) `shouldBe` c

    onGlitterWith
      (expected </> "reduction")
      ( \a () -> do
          createDirectoryIfMissing True a
          forM_ (take 20 $ iinputs (reduceC c)) \(i, c') -> do
            let rfile = expected </> "reduction" </> "r" <> debugShow i <.> "c"
            render rfile c'
      )
      do
        it "should validate all reductions" . mapM_ $ \a -> do
          validate a

validate :: FilePath -> IO ()
validate fp = do
  ec <- runProcess (proc "clang" ["-o", "/dev/null", fp])
  case ec of
    ExitFailure _ -> fail ("could not validate " <> show fp)
    ExitSuccess -> pure ()

render :: FilePath -> C.CTranslUnit -> IO ()
render cto c = do
  createDirectoryIfMissing True (takeDirectory cto)
  writeFile cto (P.render (C.pretty c) <> "\n")

parse :: FilePath -> IO C.CTranslUnit
parse cfrom = do
  cf <- C.parseCFile (C.newGCC "clang") Nothing [] cfrom
  case cf of
    Left err -> fail (show err)
    Right cf' -> pure cf'